Please, answer your questions as: 1 PM, 2 AM etc.
Procedures
The above updated MicroWorlds version was created as an eighth grade class project during the school year 1999-2000.
The following article was published in Logo Exchange, Vol 11 Number 4, Summer 1993, by the International Society for Technology in Education, ISTE.
Orlando Mihich, JHS 118
Spring 1992
Introduction.
Students always like to draw maps for the Social Studies
class. They particularly like, and are very proud of, their creations
in LogoWriter. They add colors, text, and each map is
“unique,” at times awkward-looking, but clear in what it
represents. The process is usually lengthy because students are
pursuing the “perfect map” by drawing and redrawing lines.
Students copy maps from the Social Studies book and from the Atlas.
When the size of the map matches the size of the screen, they trace
the map on a piece of transparent paper, paste the paper on the
screen and drive the turtle following the traced lines. Recently,
some students were drawing a map of the Mediterranean Sea and the
Roman Empire. One student had the Italian peninsula, the
“boot,” looking east instead of west. The student was
copying a very small map from the Social Studies book, a map that
couldn’t be traced on paper for transfer onto the screen, and
got lost in the process.
To help students generate more accurate drawings, and avoid the map
size obstacle, the grid., i.e. the “old masters’
technique,” is a very helpful tool. It has been used for
centuries for copying, enlarging and reducing before today’s
xerox revolution.
Logo
Maps. Students first draw a
grid on the computer screen and number a vertical and a horizontal
bar of squares; a 6 x 9 grid is quite adequate. Next, on a piece of
tracing paper they trace the state or continent and, depending on the
size of the map, procede to draw a proportionate 6 x 9 grid over the
traced work. This way, the map on the paper is broken down into
squares and defined by the vertical and horizontal numbers. Now,
students are ready to drive the turtle on the screen, from square to
square, following the traced outline from the paper grid.
Before students start driving the turtle around the screen, we
discuss ways to make the work easier and speedier. Sooner or later
they come up with Tom Laugh’s “forward and back,” or
“fb” procedure:
to fb :size
ht fd :size wait 25
pe bk :size pd st
end
With this procedure, students can evaluate a line several times
before accepting it. When satisfied with a specific line, they simply
change the fb into an fd and retain the value for the
line. Students are further challenged to incorporate the above
procedure into new procedures to turn the turtle right or left, and
draw a line:
to r :angle :size
rt :angle fb :size lt :angle
end
to l :angle :size
lt :angle fb :size rt :angle
end
Here too, students retain the numeric values adding a t to the
r or l, and a fd to the second number. The final
result in creating a map of the U.S. should look something like
this:
The starting procedures are as follows:
to startup
rg ht
grid 30 numbers 30
usa.map
end
to square :s
repeat 4[fd :s rt 90]
end
to grid :s
pu setpos [-135 -89] pd
repeat 3[repeat 2[repeat 9[square :s rt 90 fd :s lt
90]
fd :s * 2 rt 180]
fd :s * 2]
end
to numbers :s
pu setpos [-132 -82] pd label [1]
pu fd :s pd label [2] pu fd :s pd label [3]
pu fd :s pd label [4] pu fd :s pd label [5]
pu fd :s pd label [6]
pu fd :s / 3 rt 90
pu fd :s / 3 pd label [1]
pu fd :s pd label [2] pu fd :s pd label [3]
pu fd :s pd label [4] pu fd :s pd label [5]
pu fd :s pd label [6] pu fd :s pd label [7]
pu fd :s pd label [8] pu fd :s pd label [9]
end
to usa.map
pu setpos [85 -70] pd seth 0
lt 40 fd 22 rt 40 fd 5
lt 40 fd 10 lt 50 fd 25
lt 90 fd 5 rt 90 fd 22
lt 45 fd 25 lt 45 fd 7
rt 90 fd 3 rt 45 fd 30
lt 45 fd 6 lt 45 fd 4
rt 80 fd 25 lt 35 fd 6
lt 90 fd 3 rt 90 fd 10
rt 35 fd 20 rt 55 fd 3
lt 90 fd 12 rt 90 fd 3
and so on!
end
The generated maps are still individual, personal maps, only they are
more accurate and easier to make. By the end of the project, students
are masters in spacial orientation and, in addition, have learned a
technique they may find helpful in the future.
In the Social Studies class, students usually add to the completed
maps the country’s major cities, mineral occurencies, dominant
land use, the flag, the national anthem, and so on. The Earth Science
curriculum is enriched by students creating their own weather maps,
positioning weather fronts, indicating areas of high and low
pressure, and temperatures. Students exchange their weather maps,
make educated guesses and predict the movement of air masses and the
next day’s weather.
N.B. Professor Francisco Quesada of the Universidad de Costa Rica in San Jose, Costa Rica, in his paper “Easy Map Drawing with LogoWriter,” Logo Exchange Dec/Jan 1990, introduces map-making procedures that automatically collect the list of instructions in the command center and carry them on the flip side.
Standard Time Zones.
The earth’s surface is divided into 24 standard time zones. In
each zone, noon is set as the time when the the sun is highest over
the center of that zone. The time in each zone is one hour earlier
than the time in the zone to the east, e.g. at nine o’clock in
New York City, it is eight o’clock in Houston, and six
o’clock in Los Angeles.
My eighth grade students divide the U.S. map into the four time zones
and add several cities around the country. Positioning the turtle in
a starting city, they direct the turtle-plane to “set the
heading toward” the destination city and fly to that city. In
addition, they add a quiz asking the viewer to type in the arrival
time, and to adjust the watch to the local time for the time
difference. At the end of all flights, the program gives the number
of correct and incorrect answers. My students are very creative and
every year they change the program enriching it with new ideas in
screen design and programming.
The following quiz was written by Antonio Colondres on an Apple IIgs.
Antonio created five aeroplane shapes and had the turtle flying from
New York to four cities in the U.S.A. At each stop, the viewer is
asked to type the local time or to adjust his/her watch to the local
time and, if the answer is correct, the clocks on the screens change
accordingly. At the end of the quiz, the program gives the number of
correct and incorrect answers, and the % of correct answers.
The procedures for the quiz, which include one flight and one change
of time, are as follows:
to startup
rg ht ct cc
usa.map
time.zones
cities
time0
introduction
end
to time0
setc 1 pu setpos [95 -85] setsh 52 pd stamp
pu setpos [25 -85] setsh 51 pd stamp
pu setpos [-45 -85] setsh 50 pd stamp
pu setpos [-115 -85] setsh 49 pd stamp
end
to introduction
make "correct 0
make "total 0
make "wrong 0
cc type[Hi, my name is Antonio and your name is?]
type char 13
make "name readlistcc
cc type se [Type a key] :name type se ", [and get ready
for a tour of the United States and some questions.]
make "key readchar
question1
end
to go
if colorunder = 2 [stop]
pu fd 1
go
end
to ny.sf
pu setpos [98 36]
setc 2 setsh 2 st
seth towards [-118 13]
pu fd 5 go
end
to question1
cc type [Your plane leaves New York at 11 am and will reach San
Francisco in 5 hours. What is the local time in San
francisco?]
type char 13
tell 0 ny.sf
make "answer first readlistcc
ifelse :answer = 1 [cc type [Quite correct! The local time in
San Francisco is 1 pm.
Type a key to continue.]
tell 1 time1
type char 13
make "key readchar
make "correct :correct + 1 make "total :total + 1 cc question2
stop]
[cc type (se "Sorry, :name [. Your answer is incorrect. Type
a key to continue and try again.])
make "wrong :wrong + 1 make "total :total + 1
make "key readchar
cc question1r]
end
to question1r
tell 0 pu setpos [98 36]
cc type [Your plane leaves New York at 11 am and will reach San
Francisco in 5 hours. What is the local time in San
francisco?]
type char 13
ny.sf
make "answer first readlistcc
ifelse :answer = 1 [cc type [Quite correct! The local time in
San Francisco is 1 pm. Type a key to continue.]
tell 1 time1
type char 13
make "key readchar
make "correct :correct + 1 make "total :total + 1 cc question2
stop]
[cc type (se "Sorry, :name [. Your answer is incorrect. The
time in San Francisco is 1 pm. Type a key to continue.])
tell 1 time1
make "wrong :wrong + 1 make "total :total + 1
make "key readchar
cc question2]
end
to time1
pu setpos [95 -85] setsh 52 pe stamp setsh 45 pd stamp
pu setpos [25 -85] setsh 51 pe stamp setsh 44 pd stamp
pu setpos [-45 -85] setsh 50 pe stamp setsh 43 pd stamp
pu setpos [-115 -85] setsh 49 pe stamp setsh 42 pd stamp
end
to ending
cc type (se [You have] :correct [correct answers and]
:wrong [wrong,] :name ".)
type char 13
type [Type a key.]
make "key readchar
cc type (se [Your score is] :correct / :total * 100 "%!)
type char 13
type [Type a key.]
make "key readchar
cc type [If you want to restart the program type R otherwise
press any other key.]
type char 13
ifelse readchar = "R [time7 question1]
[leavepage]
end
Time7 restores the clocks to the initial time0.