This vector could represent a wind blowing from 45 degrees west of south with a magnitude of 50 mph.
The following article was published by ISTE’s Logo Exchange, Vol. 11 No. 2, 1992.
Introduction.
Some physical quantities, such as length, volume,
mass, and time, can be expressed in terms
of magnitude alone, as single numbers. The height of a table is
completely defined as 0.73 meters, and a carton of milk as 2 liters.
These quantities, expressed completely by single numbers, are called
scalars.
Other physical quantities, such as force,
acceleration, velocity, cannot be fully described in
terms of magnitude alone. In addition to magnitude, these quantities
have a specific direction. These quantities are called
vectors. They are usually shown as arrows.
This vector could represent a wind blowing from 45 degrees west of south with a magnitude of 50 mph.
When two forces, F1 and F2, act on the same point at an angle other than 0 or 180 degrees the resultant force, R, can be found by the parallelogram method.
An object, under the effect of the two forces,
will move along the diagonal of the parallelogram of forces, i.e.,
the resultant force, R.
The object will remain in a state of equilibrium when an opposing
force balance the effect of the resultant force, R. The
equilibrant force, E, must have the same magnitude and
act in the opposite direction.
F1 70 55
F2 70 125
R 115 90
E 115 270
.
In the above values, the first number represents the
magnitude, the length of the line of the vector; the second number
represents the heading of the vector, as indicated by the arrow.
In LogoWriter, 0 degrees is North (toward the top of the screen), 90
degrees is East (towards the right of the screen), 180 degrees is
South (towards the bottom of the screen), and 270 degrees is West
(towards the left of the screen).
F1 50 0
F2 50 135
R 38 68
The Graphic
Solution. The resultant force can
be found by drawing the parallelogram accurately to scale, and
measuring the magnitude of the diagonal with a ruler. At the Junior
High School level, students use graph paper, a ruler and a protractor
to find the magnitude of the resultant force. Results will vary
slightly from student to student.
The LogoWriter
Solution. The Junior High School
student can write a program to draw the two forces and the resultant,
and find the values for magnitude and heading without knowing the
laws of sines and cosines. The following program will draw the two
forces, the resultant, and the equilibrant force:
to startup
rg ht ct cc
tell [0 1 2] pu setpos [0 0]
make "start [0 0]
type [Introduce magnitude and direction for]
type char 13
type [Vector1]
type char 32
end
to arrow
rt 45 bk 5 fd 5
lt 90 bk 5 fd 5
rt 45
end
to vector1 :magnitude1 :direction1
make "m1 :magnitude1
make "d1 :direction1
tell 0 ht setc 2
seth :direction1 pd fd :magnitude1
arrow
pu fd 12 pd label [F1] pu bk 12 pd
pr (se [F1] :magnitude1 :direction1)
type [Introduce magnitude and direction for]
type char 13
type [Vector2]
type char 32
end
to vector2 :magnitude2 :direction2
make "m2 :magnitude2
make "d2 :direction2
tell 1 ht setc 2
seth :direction2 pd fd :magnitude2
arrow
pu fd 12 pd label [F2] pu bk 12
bk :magnitude2 pd
pr (se [F2] :magnitude2 :direction2)
cc type [Press the return key.]
type char 13
type [Resultant]
end
to resultant
tell 0 seth :d2 pu fd :m2
make "p pos
tell 2 setc 5 seth towards ask 0 [pos]
make "h heading
pd setpos :p
arrow
pu fd 12 pd label [R] pu bk 12 pu setpos :start
make "d distance ask 0 [pos]
pr (se [R] round :d round :h)
cc type [Press the return key.]
type char 13
type [Equilibrant]
end
to equilibrant
tell 2 seth (:h + 180) pd fd :d
arrow
pu fd 12 pd label [E] pu bk 12
pr (se [E] round distance ask 1 [pos] round
heading)
cc type [Type a key to restart.]
type char 13
make "key readchar
startup
end
The program asks to introduce magnitude and
direction for vector1, and then vector2. Typing the two numbers for
Vector1, e.g. 50 for magnitude and 45 for direction, will draw a line
of 50 turtle steps (50 newtons), and set the turtle’s heading at
45 degrees (NE). After the second vector is introduced, the
resultant, R, is the diagonal vector connecting the point of
origin of the two vectors and the opposite corner of the
parallelogram. Since opposite sides of the parallelogram are equal,
the turtle in vector1 draws vector1, then, in resultant, follows the
instructions for magnitude and direction of vector2 and “make a
position” for drawing the resultant. The resultant’s
magnitude and heading are obtained by asking the turtle in the
opposite corner of the parallelogram for the respective values. The
equilibrant force is identical in magnitude to the resultant force
only heading in the opposite direction (heading + 180).
The Trigonometric Logo
Solution. The resultant of two
vectors acting at an acute or obtuse angle is usually found
trigonometrically by the laws of sines and cosines. The equation for
the resultant is as follows:
F12 + F22
- 2F1F2 cos 180 - A
where A is the angle between
the two forces, F1 and F2.
Here F12 = h2 + p2
F22 = h2 + (R - p)2
F22 = F12 - p2 + R2 - 2Rp
+ p2
F22 = F12 + R2 - 2Rp
p = F1 cos a
F22 = F12 + R2 - 2 R F1 cos
a
similarly R2 = F12 + F22 - 2 F1
F2 cos B
or R2 = F12 + F22 - 2 F1 F2 cos
180 - A
The Logo resultant for the two vectors, F1
magnitude1 direction1, and F2 magnitude2 direction2, is as
follows:
to resultant :F1 :F2
op sqrt ((sq first :F1) + (sq first :F2))
- (2 * (first :F1) * (first :F2))
* cos 180 - ((last :F1) - (last :F2))
end
Multiple
Vectors. There are two ways of
finding the resultant of two or more vectors acting at the same
point.
A. Using the parallelogram method, the resultant of the first two
vectors is used with a third vector to find the the second resultant;
the second resultant is used with a fourth vector to find the third
resultant, and so on, until the last vector is introduced, and the
final resultant is obtained. The following program starts with
a vector of 0 magnitude and 0 direction (make “r [0 0]),
therefore the first typed vector is also the first resultant.
to startup
rg ht ct cc
make "start [0 0]
make "r [0 0]
v
end
to arrow
rt 45 bk 5 fd 5
lt 90 bk 5 fd 5
rt 45
end
to v
cc type [Type magnitude and direction for vector.]
type char 13
make "v readlistcc
setc 2
seth (last :v) pd fd (first :v)
arrow
bk (first :v)
pr (se (first :v) (last :v))
r
end
to r
seth (last :r) pu fd (first :r)
seth (last :v) fd (first :v)
make "p pos
pu setpos :start
seth towards :p
make "h heading
setc 5
pd setpos :p
arrow
pu fd 12 pd label [R] pu
setpos :start pd
pr (se [R] round resultant :r :v round :h)
make "r list round resultant :r :v round :h
v
end
to resultant :r :v
op sqrt ((sq first :r) + (sq first :v))
-(2 * (first :r) * (first :v))
* cos 180 - ((last :r) - (last :v))
end
to sq :n
op :n * :n
end
The multiple vectors screen:
B. A shortcut for the parallelogram of
forces is to place vectors head to tail. The resultant force, R, is a
straight line connecting the tail of the first vector with the head
of the last vector. The orientation of the resultant is toward the
head of the last vector.
to startup
rg ht ct cc
setup
pr [To add a vector type V, and introduce magnitude]
pr [and direction, then type R.]
end
to setup
tell [0 1]
ht pu setpos [0 0]
end
to arrow
rt 45 bk 5 fd 5
lt 90 bk 5 fd 5
rt 45
end
to v :m :d
tell 0 setc 2
seth :d pd fd :m
arrow
pr (se :m :d)
end
to r
tell 0 make "p pos
tell 1 make "o pos
seth towards ask 0 [pos]
setc 5 pd setpos :p arrow
pu setpos :o
pr (se [R] round magnitude round direction)
end
to magnitude
tell 1 op distance ask 0 [pos]
end
to direction
tell 1 op heading
end
The head to tail screen:
50 45
70 135
30 270
60 0
40 335
50 270
R 83 352
The
Classroom. In the classroom
students explore forces by engaging in various activities, e.g.,
pulling a heavy object like the teacher’s desk. The desk moves
following the resultant force, and eventually students discover that
the closer they stay, the easier it is to pull the desk. In another
activity, two students pull a rope at the ends while a third student
in the middle resists the pull. This student discovers that as the
angle between the two students pulling the rope increases, the easier
it gets to resist the pull and maintain equilibrium.
In the Salvadori Class “Why Buildings Stands Up,” my
students engage in many similar activities. This class deals with the
real environment; students use their intellectual and manual skills
to learn about and create an environment they are familiar with: the
buildings and bridges surrounding them in everyday life. Students
also love to work on computers and using LogoWriter they become the
“architect-programmer.” They teach the computer to show how
forces act on structures; they write programs for forces in
equilibrium, and the effect of wind forces on buildings; they
generate screens to show tension and compression forces in a truss
bridge, and so on. The following is one example of such
actvities.
The Truss
Bridge. By holding hands firmly and
pulling, students experience tension “first hand.” When
they push at each other, without bending their arms, they
“feel” compression. Tension is also demonstrated by
stretching a rubber band. The increased length shows that tension
lengthens. Squeezing a sponge shows that compression shortens.
Trusses are structures made out of bars that work either in tension
or compression without bending. A truss bridge is made of triangular
trusses. Students build bridges out of tongue depressors, and
determine which bar is in tension or compression by substituting a
string for the depressor. The string in tension becomes a straight
line.
A LogoWriter Structure with a folded plate
roof. Building a Lego truss bridge capable of rotating on a
central pier via a logo program. The Lego truss bridge. ...and just for the fun of it: The tower of Pisa built
with LogoWriter screens.
Bibliography
Tempel, Michael. (1992). Advanced Logo Seminar Handouts.
Salvadori, Mario. (1979). Buildings - from Caves to Skyscrapers. The
Salvadori Educational Center on the Built Environment.
Lewis, Philip G.. (1990). Approaching Precalculus Mathematics
Discretely. MIT.
Trinklein, Frederick. (1990). Modern Physics. Holt, Rinehart and
Winston, Inc.
Apsen, Boris. (1978). Repetitorij Vise Matematike. Tehnicka
Knjiga Zagreb.